Cycloid

tt=2;Graphics[
{{Line[{{-2,0},{10,0}}]},
{GrayLevel[0.8],Point[{#-Sin[#],1-Cos[#]}]&/@Range[0,2 Pi,(Pi/64)]},
{Line[{{tt,1},{tt,1}+{-Sin[tt+#],-Cos[tt+#]}}]&/@Range[0,2 Pi,((2 Pi)/5)]},
{Thickness[0.006],Circle[{tt,1},1]},
{RGBColor[0.5,0,.5],PointSize[0.02],Point[{tt-Sin[tt],1-Cos[tt]}]}
},
PlotRange->{{-1.2,2 Pi+1},{-.1,2.2}},
Frame->True,Axes->False,FrameTicks->{Range[0,2 Pi,((2 Pi)/5)],{0,1,2},None,None}

]

Or slightly improved, with the purple point leaving a light 
purple trail.

tt=2;Graphics[
{{Line[{{-2,0},{10,0}}]},
{GrayLevel[0.8],Point[{#-Sin[#],1-Cos[#]}]&/@Range[0,2 Pi,(Pi/64)]},
{Line[{{tt,1},{tt,1}+{-Sin[tt+#],-Cos[tt+#]}}]&/@Range[0,2 Pi,((2 Pi)/5)]},
{Thickness[0.006],Circle[{tt,1},1]},
{RGBColor[0.75,0.5,0.75],PointSize[0.01],Point[{#-Sin[#],1-Cos[#]}]&/@Range[0,tt,(Pi/64)]},
{RGBColor[0.5,0,.5],PointSize[0.02],Point[{tt-Sin[tt],1-Cos[tt]}]}
},
PlotRange->{{-1.2,2 Pi+1},{-.1,2.2}},
Frame->True,Axes->False,FrameTicks->{Range[0,2 Pi,((2 Pi)/5)],{0,1,2},None,None}

]

Clear[tt];Manipulate[Graphics[
{{Line[{{-2,0},{10,0}}]},
{GrayLevel[0.8],Point[{#-Sin[#],1-Cos[#]}]&/@Range[0,2 Pi,(Pi/64)]},
{Line[{{tt,1},{tt,1}+{-Sin[tt+#],-Cos[tt+#]}}]&/@Range[0,2 Pi,((2 Pi)/5)]},
{Thickness[0.006],Circle[{tt,1},1]},
{RGBColor[0.75,0.5,0.75],PointSize[0.01],Point[{#-Sin[#],1-Cos[#]}]&/@Range[0,tt,(Pi/64)]},
{RGBColor[0.5,0,.5],PointSize[0.02],Point[{tt-Sin[tt],1-Cos[tt]}]}
},
PlotRange->{{-1.2,2 Pi+1},{-.1,2.2}},
Frame->True,Axes->False,FrameTicks->{Range[0,2 Pi,((2 Pi)/5)],{0,1,2},None,None}

],{tt,0,2Pi}]

Folium of Decartes

Recall the Folium of Decartes that we discussed as an implicit equation.

FoD=ContourPlot[(x^3)+(y^3)-6 x y==0,{x,-5,5},{y,-5,5},ContourStyle->{{Thickness[0.007],RGBColor[0,0,.5]}}]

Replace y by t x and solve for x and y we get

Solve[{(x^3)+(y^3)-6 x y==0,y==t x},{x,y}]

Thus we have a parametric equations for the Folium of Decartes

Manipulate[Show[FoD,Graphics[{PointSize[0.02],Red,Point[{((6 t)/(1+(t^3))),((6 (t^2))/(1+(t^3)))}]}],PlotRange->{{-5,5},{-5,5}},ImageSize->300],{{t,0},-20,20}]

Or, with memorizing points for t>-1

Manipulate[Show[FoD,Graphics[{{PointSize[0.012],RGBColor[1,0,0],Point[{((6 #)/(1+((#)^3))),((6 ((#)^2))/(1+((#)^3)))}]&/@Range[-1+.01,t,(1/50)]},{PointSize[0.02],Red,Point[{((6 t)/(1+(t^3))),((6 (t^2))/(1+(t^3)))}]},{Text[Style["t",FontSize->16,Italic],{0,4.7}],Text[Style["=",FontSize->16],{0.275,4.7}],Text[Style[NumberForm[N[t],{3,2}],FontSize->16],{1.1,4.7}]}}],PlotRange->{{-5,5},{-5,5}}],{{t,0},-0.99,20}]

Or, with memorizing points for t<-1

Manipulate[Show[FoD,Graphics[{{PointSize[0.012],RGBColor[1,0,0],Point[{((6 #)/(1+((#)^3))),((6 ((#)^2))/(1+((#)^3)))}]&/@Range[t,-1-.01,(1/50)]},{PointSize[0.02],Red,Point[{((6 t)/(1+(t^3))),((6 (t^2))/(1+(t^3)))}]},{Text[Style["t",FontSize->16,Italic],{0,4.7}],Text[Style["=",FontSize->16],{0.275,4.7}],Text[Style[NumberForm[N[t],{3,2}],FontSize->16],{1.1,4.7}]}}],PlotRange->{{-5,5},{-5,5}},ImageSize->300],{{t,-2},-20,-1.01}]

FullSimplify[D[{((6 t)/(1+(t^3))),((6 (t^2))/(1+(t^3)))},t]]

{a,b}.{x,y}

{a,b}.{a,b}

FullSimplify[{((6-12 (t^3))/(((1+(t^3)))^2)),-((6 t (-2+(t^3)))/(((1+(t^3)))^2))}.{((6-12 (t^3))/(((1+(t^3)))^2)),-((6 t (-2+(t^3)))/(((1+(t^3)))^2))}]

FullSimplify[(Sqrt[((36 (1+(t^2) (4-4 t-4 (t^3)+4 (t^4)+(t^6))))/(((1+(t^3)))^4))]),t>0]

Plot[((6 (Sqrt[1+(t^2) (4-4 t-4 (t^3)+4 (t^4)+(t^6))]))/(((1+(t^3)))^2)),{t,-5,5}]

Cardioid

Roll the navy blue circle on the gray unit circle.

tt=1;Graphics[
{
(* spokes on the road *)

{Thickness[0.003],GrayLevel[0.5],Line[{{0,0},{Cos[#],Sin[#]}}]&/@Range[0,2 Pi-((2 Pi)/5),((2 Pi)/5)]},
(* road *) 

{Thickness[0.006],GrayLevel[0.5],Circle[{0,0},1]},

(* the spokes on the wheel *)

{Thickness[0.003],RGBColor[0,0,.5],Line[{2{Cos[tt],Sin[tt]},2{Cos[tt],Sin[tt]}+{-Cos[2 tt+#],-Sin[2 tt+#]}}]&/@Range[0,2 Pi-((2 Pi)/5),((2 Pi)/5)]},
(* the wheel *)

{Thickness[0.006],RGBColor[0,0,.5],Circle[2{Cos[tt],Sin[tt]},1]},

(* the purple point *) 

{PointSize[0.02],RGBColor[0.5,0,0.5],Point[2{Cos[tt],Sin[tt]}-{Cos[2tt],Sin[2tt]}]}
},
PlotRange->{{-3.2,3.2},{-3.2,3.2}},
Frame->True,AspectRatio->Automatic

]

Clear[tt];Manipulate[Graphics[
{
(* spokes on the road *)

{Thickness[0.003],GrayLevel[0.5],Line[{{0,0},{Cos[#],Sin[#]}}]&/@Range[0,2 Pi-((2 Pi)/5),((2 Pi)/5)]},
(* road *) 

{Thickness[0.006],GrayLevel[0.5],Circle[{0,0},1]},

(* the spokes on the wheel *)

{Thickness[0.003],RGBColor[0,0,.5],Line[{2{Cos[tt],Sin[tt]},2{Cos[tt],Sin[tt]}+{-Cos[2 tt+#],-Sin[2 tt+#]}}]&/@Range[0,2 Pi-((2 Pi)/5),((2 Pi)/5)]},
(* the wheel *)

{Thickness[0.006],RGBColor[0,0,.5],Circle[2{Cos[tt],Sin[tt]},1]},

(* the purple point *) 
{PointSize[0.01],RGBColor[0.75,0.5,0.75],Point[2{Cos[#],Sin[#]}-{Cos[2#],Sin[2#]}]}&/@Range[0,tt,(Pi/64)],

{PointSize[0.02],RGBColor[0.5,0.,0.5],Point[2{Cos[tt],Sin[tt]}-{Cos[2tt],Sin[2tt]}]}
},
PlotRange->{{-3.2,3.2},{-3.2,3.2}},
Frame->True,AspectRatio->Automatic

],{tt,0,2 Pi}]